Generic Query that raise error when execute Find

Hi,

I have created a base class of T that I will inherits in many other class because I don't want to implement the Find and FindById in each specific class.

Here is want I have made for the function Find:

      Public Function FindAll() As Generic.IList(Of Mindscape.LightSpeed.Entity(Of T))
         Dim unitOfWork As Mindscape.LightSpeed.IUnitOfWork
         Dim list As Generic.IList(Of Mindscape.LightSpeed.Entity(Of T))

         unitOfWork = ContextProvider.Context.CreateUnitOfWork

         Using unitOfWork
            list = unitOfWork.Find(Of Mindscape.LightSpeed.Entity(Of T))()
         End Using

         Return list
      End Function

      Public Function FindById(ByVal id As Object) As Mindscape.LightSpeed.Entity(Of T)
         Dim unitOfWork As Mindscape.LightSpeed.IUnitOfWork
         Dim entity As Mindscape.LightSpeed.Entity(Of T)

         unitOfWork = ContextProvider.Context.CreateUnitOfWork

         Using unitOfWork
            entity = unitOfWork.FindById(Of Mindscape.LightSpeed.Entity(Of T))(id)
         End Using

         Return entity
      End Function

But when the system try to execute the Find method of UnitOfWork, this raise the following error:

"Incorrect syntax near the keyword 'FROM'."

What is wrong with my statements and how can I correct it.

Thank you very much.

The problem lies in this call:

  Find(Of Mindscape.LightSpeed.Entity(Of T))

In Entity(Of T), T is the ID type, *NOT* the entity type.  So this is basically asking "get me all entities with (say) integer IDs."  And LightSpeed can't do this.  LightSpeed requires you to query for a particular type of entity.

I think what you're trying to do is query for all entities of type T -- e.g. all Products -- where T is an entity type.  To do this, you need to write:

      Public Function FindAll(Of T)() As IList(Of T As Entity)
         Dim unitOfWork As Mindscape.LightSpeed.IUnitOfWork
         Dim list As IList(Of T)

         unitOfWork = ContextProvider.Context.CreateUnitOfWork

         Using unitOfWork
            list = unitOfWork.Find(Of T)()
         End Using

         Return list
      End Function

And similarly for FindById(Of T).

Does that meet your requirement?

All work fine now. Just for the context, I have created this functions because I have built a web site with asp mvc and I don't want to implement the CRUD operations for each of my screen corresponding to tables in database.

I have created a BaseController(of T) with Create, Edit, Delete and List both Get and Post.

For other who want this type of implementation, here is my bunch of code with the help of LightSpeed member. It work now perfectly.

Imports System.Collections.Generic
Imports Mindscape.LightSpeed.Linq
Imports Mindscape.LightSpeed.Logging

Namespace NeoSynergix.Repository
   Public MustInherit Class BaseRepository(Of T As Mindscape.LightSpeed.Entity)
      Private _unitOfWork As Mindscape.LightSpeed.IUnitOfWork

      Public Sub New(ByVal unitOfWork As Mindscape.LightSpeed.IUnitOfWork)
         _unitOfWork = unitOfWork
      End Sub

      Public Overridable Function Create() As T
         Return DirectCast(Activator.CreateInstance(GetType(T)), T)
      End Function

      Public Overridable Function Query() As IQueryable(Of T)
         Return _unitOfWork.Query(Of T)()
      End Function

      Public Overridable Function Find() As Generic.IList(Of T)
         Return _unitOfWork.Find(Of T)()
      End Function

      Public Overridable Function FindById(ByVal id As Object) As T
         Return _unitOfWork.FindById(Of T)(id)
      End Function

      Public Overridable Sub Delete(ByVal entities As IEnumerable(Of T))
         For Each entity As T In entities
            _unitOfWork.Remove(entity)
         Next

         _unitOfWork.SaveChanges()
      End Sub

      Public Overridable Sub Update(ByVal entities As IEnumerable(Of T))
         For Each entity As T In entities
            _unitOfWork.Attach(entity)
         Next

         _unitOfWork.SaveChanges()
      End Sub

      Public Overridable Function Add(ByVal entities As IEnumerable(Of T)) As Boolean
         For Each entity As T In entities
            _unitOfWork.Add(entity)
         Next

         _unitOfWork.SaveChanges()

         Return True
      End Function

      Public Overridable Function Delete(ByVal entity As T) As Boolean
         _unitOfWork.Remove(entity)

         _unitOfWork.SaveChanges()

         Return True
      End Function

      Public Overridable Function Update(ByVal entity As T) As Boolean
         _unitOfWork.Attach(entity)

         _unitOfWork.SaveChanges()

         Return True
      End Function

      Public Overridable Function Add(ByVal entity As T) As Boolean
         _unitOfWork.Add(entity)

         _unitOfWork.SaveChanges()

         Return True
      End Function
   End Class
End Namespace

Thank you very much again. Now I can use of powerful ORM with the RAD advantage adhoc SQL queries.